//+--------------------------------------------------------------------+
//| Copyright:  (C) 2015 Forex Software Ltd.                           |
//| Website:    http://forexsb.com/                                    |
//| Support:    http://forexsb.com/forum/                              |
//| License:    Proprietary under the following circumstances:         |
//|                                                                    |
//| This code is a part of Forex Strategy Builder. It is free for      |
//| use as an integral part of Forex Strategy Builder.                 |
//| One can modify it in order to improve the code or to fit it for    |
//| personal use. This code or any part of it cannot be used in        |
//| other applications without a permission.                           |
//| The contact information cannot be changed.                         |
//|                                                                    |
//| NO LIABILITY FOR CONSEQUENTIAL DAMAGES                             |
//|                                                                    |
//| In no event shall the author be liable for any damages whatsoever  |
//| (including, without limitation, incidental, direct, indirect and   |
//| consequential damages, damages for loss of business profits,       |
//| business interruption, loss of business information, or other      |
//| pecuniary loss) arising out of the use or inability to use this    |
//| product, even if advised of the possibility of such damages.       |
//+--------------------------------------------------------------------+

#property copyright "Copyright (C) 2015 Forex Software Ltd."
#property link      "http://forexsb.com"
#property version   "1.00"
#property strict

#include <Forexsb.com/Indicator.mqh>
#include <Forexsb.com/Enumerations.mqh>
#include <Forexsb.com/Indicators/CommodityChannelIndex.mqh>
//## Requires CommodityChannelIndex.mqh

class CCIBuySellZones : public Indicator
{
    public:
        CCIBuySellZones(SlotTypes slotType)
        {
            SlotType = slotType;

            IndicatorName = "CCI Buy Sell Zones";

            WarningMessage    = "";
            IsAllowLTF        = true;
            ExecTime          = ExecutionTime_DuringTheBar;
            IsSeparateChart   = true;
            IsDiscreteValues  = false;
            IsDefaultGroupAll = false;
        }

        virtual void Calculate(DataSet &dataSet);
};

void CCIBuySellZones::Calculate(DataSet &dataSet)
{
    Data = GetPointer(dataSet);

    // Reading the parameters
    MAMethod maMethod=(MAMethod) ListParam[2].Index;
    int periodCci = (int) NumParam[0].Value;
    int periodMa  = (int) NumParam[1].Value;
    int level     = (int) NumParam[2].Value;
    int previous  = CheckParam[0].Checked ? 1 : 0;

    // Calculation
    int firstBar = periodCci + periodMa + 2;

    CommodityChannelIndex *cciIndicator = new CommodityChannelIndex(SlotType);
    cciIndicator.ListParam[1].Index    = ListParam[1].Index;
    cciIndicator.ListParam[2].Index    = ListParam[3].Index;
    cciIndicator.NumParam[0].Value     = NumParam[0].Value;
    cciIndicator.NumParam[1].Value     = 100;
    cciIndicator.NumParam[2].Value     = 0.015;
    cciIndicator.CheckParam[0].Checked = CheckParam[0].Checked;
    cciIndicator.Calculate(dataSet);

    double cci[];
    ArrayResize(cci, Data.Bars);
    ArrayCopy(cci, cciIndicator.Component[0].Value);
    delete cciIndicator;

    double maCci[];
    MovingAverage(periodMa,0,maMethod,cci,maCci);

    double buyZone[];  ArrayResize(buyZone, Data.Bars);  ArrayInitialize(buyZone, 0);
    double sellZone[]; ArrayResize(sellZone, Data.Bars); ArrayInitialize(sellZone, 0);

    for (int bar = firstBar; bar < Data.Bars; bar++)
    {
        if (buyZone[bar - 1] > Sigma() && maCci[bar] < -level)
        {
            // Continue Buy zone
            buyZone[bar] = 1;
            continue;
        }

        if (sellZone[bar - 1] > Sigma() && maCci[bar] > level)
        {
            // Continue Sell zone
            sellZone[bar] = 1;
            continue;
        }

        if (cci[bar] > maCci[bar] + Sigma() && cci[bar - 1] <= maCci[bar - 1] &&
            maCci[bar] < -level)
        {
            // Start Buy zone
            buyZone[bar] = 1;
            continue;
        }

        if (cci[bar] < maCci[bar] - Sigma() && cci[bar - 1] >= maCci[bar - 1] &&
            maCci[bar] > level)
        {
            // Start Sell zone
            sellZone[bar] = 1;
        }
    }

    // Shift signal if it is necessary
    if (previous > 0)
    {
        for (int bar = Data.Bars - 1; bar >= firstBar; bar--)
        {
            buyZone[bar]  = buyZone[bar - 1];
            sellZone[bar] = sellZone[bar - 1];
        }
    }

    // Saving the components
    ArrayResize(Component[0].Value,Data.Bars);
    Component[0].CompName = "CCI";
    Component[0].DataType = IndComponentType_IndicatorValue;
    Component[0].FirstBar = firstBar;
    ArrayCopy(Component[0].Value, cci);

    ArrayResize(Component[1].Value,Data.Bars);
    Component[1].CompName = "MA CCI";
    Component[1].DataType = IndComponentType_IndicatorValue;
    Component[1].FirstBar = firstBar;
    ArrayCopy(Component[1].Value, maCci);

    ArrayResize(Component[2].Value, Data.Bars);
    Component[2].FirstBar = firstBar;

    ArrayResize(Component[3].Value, Data.Bars);
    Component[3].FirstBar = firstBar;

    // Sets the Component's type
    if (SlotType == SlotTypes_OpenFilter)
    {
        Component[2].DataType = IndComponentType_AllowOpenLong;
        Component[2].CompName = "Is long entry allowed";
        ArrayCopy(Component[2].Value, buyZone);
        Component[3].DataType = IndComponentType_AllowOpenShort;
        Component[3].CompName = "Is short entry allowed";
        ArrayCopy(Component[3].Value, sellZone);
    }
    else if (SlotType == SlotTypes_CloseFilter)
    {
        Component[2].DataType = IndComponentType_ForceCloseLong;
        Component[2].CompName = "Close out long position";
        ArrayCopy(Component[2].Value, sellZone);
        Component[3].DataType = IndComponentType_ForceCloseShort;
        Component[3].CompName = "Close out short position";
        ArrayCopy(Component[3].Value, buyZone);
    }
}