//+--------------------------------------------------------------------+
//| Copyright:  (C) 2014 Forex Software Ltd.                           |
//| Website:    http://forexsb.com/                                    |
//| Support:    http://forexsb.com/forum/                              |
//| License:    Proprietary under the following circumstances:         |
//|                                                                    |
//| This code is a part of Forex Strategy Builder. It is free for      |
//| use as an integral part of Forex Strategy Builder.                 |
//| One can modify it in order to improve the code or to fit it for    |
//| personal use. This code or any part of it cannot be used in        |
//| other applications without a permission.                           |
//| The contact information cannot be changed.                         |
//|                                                                    |
//| NO LIABILITY FOR CONSEQUENTIAL DAMAGES                             |
//|                                                                    |
//| In no event shall the author be liable for any damages whatsoever  |
//| (including, without limitation, incidental, direct, indirect and   |
//| consequential damages, damages for loss of business profits,       |
//| business interruption, loss of business information, or other      |
//| pecuniary loss) arising out of the use or inability to use this    |
//| product, even if advised of the possibility of such damages.       |
//+--------------------------------------------------------------------+

#property copyright "Copyright (C) 2014 Forex Software Ltd."
#property link      "http://forexsb.com"
#property version   "2.00"
#property strict

#include <Forexsb.com/Indicator.mqh>
#include <Forexsb.com/Enumerations.mqh>
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
class PriceMARelation : public Indicator
  {
public:
   PriceMARelation(SlotTypes slotType)
     {
      SlotType=slotType;

      IndicatorName="Price MA Relation";

      WarningMessage    = "";
      IsAllowLTF        = true;
      ExecTime          = ExecutionTime_DuringTheBar;
      IsSeparateChart   = false;
      IsDiscreteValues  = false;
      IsDeafultGroupAll = false;
     }

   virtual void Calculate(DataSet &dataSet);
  };
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PriceMARelation::Calculate(DataSet &dataSet)
  {
   Data=GetPointer(dataSet);

// Reading the parameters
   BasePrice maBasePrice=(BasePrice) ListParam[1].Index;
   MAMethod maMethod=(MAMethod) ListParam[2].Index;
   int maPeriod = (int) NumParam[0].Value;
   int previous = CheckParam[0].Checked ? 1 : 0;

   BasePrice barBasePriceLong=(BasePrice) ListParam[3].Index;
   BasePrice barBasePriceShort=barBasePriceLong;
   if(barBasePriceLong==BasePrice_High)
      barBasePriceShort=BasePrice_Low;
   if(barBasePriceLong==BasePrice_Low)
      barBasePriceShort=BasePrice_High;

   double basePrc[];  Price(maBasePrice,basePrc);
   double ma[]; MovingAverage(maPeriod,0,maMethod,basePrc,ma);
   double barLong[];  Price(barBasePriceLong,barLong);
   double barShort[]; Price(barBasePriceShort,barShort);
   int firstBar=maPeriod+previous+1;

// Saving the components
   ArrayResize(Component[0].Value,Data.Bars);
   Component[0].CompName = "Moving Average";
   Component[0].DataType = IndComponentType_IndicatorValue;
   Component[0].FirstBar = firstBar;
   ArrayCopy(Component[0].Value,ma);

   ArrayResize(Component[1].Value,Data.Bars);
   ArrayInitialize(Component[1].Value,0);
   Component[1].FirstBar=firstBar;

   ArrayResize(Component[2].Value,Data.Bars);
   ArrayInitialize(Component[2].Value,0);
   Component[2].FirstBar=firstBar;

// Sets the Component's type
   if(SlotType==SlotTypes_OpenFilter)
     {
      Component[1].DataType = IndComponentType_AllowOpenLong;
      Component[1].CompName = "Is long entry allowed";
      Component[2].DataType = IndComponentType_AllowOpenShort;
      Component[2].CompName = "Is short entry allowed";
     }
   else if(SlotType==SlotTypes_CloseFilter)
     {
      Component[1].DataType = IndComponentType_ForceCloseLong;
      Component[1].CompName = "Close out long position";
      Component[2].DataType = IndComponentType_ForceCloseShort;
      Component[2].CompName = "Close out short position";
     }

// Sets the components signals
   if(ListParam[0].Text=="Bar price is higher than MA")
     {
      for(int bar=firstBar; bar<Data.Bars; bar++)
        {
         double sigma=Sigma();
         if(barLong[bar-previous]>ma[bar-previous]+sigma)
            Component[1].Value[bar]=1;
         if(barShort[bar-previous]<ma[bar-previous]-sigma)
            Component[2].Value[bar]=1;
        }
     }
   else if(ListParam[0].Text=="Bar price is lower than MA")
     {
      for(int bar=firstBar+previous; bar<Data.Bars; bar++)
        {
         double sigma=Sigma();
         if(barLong[bar-previous]<ma[bar-previous]-sigma)
            Component[1].Value[bar]=1;
         if(barShort[bar-previous]>ma[bar-previous]+sigma)
            Component[2].Value[bar]=1;
        }
     }
  }
//+------------------------------------------------------------------+